HOW TO USE MATHEMATICA

[Rotating icosaheadron around Vandy leaf]

This web page is intended only as an introduction. Further information can be found at other websites devoted to Mathematica; a list of such sites is maintained by Wolfram.

What is Mathematica ?

Mathematica is a software system that enables you to perform numerical, symbolic and graphical computations in a unified manner. Complementing a copious amount of built-in functions is the Mathematica programming language, with which you can design your own functions to extend the capabilities of the system. Particular strengths of this versatile software lie in the symbolic manipulation of expressions, the display and animation of graphics, and the accessibility of most of mathematics' special functions already built into the system.

Running Mathematica

Version 2.2 of Mathematica runs on Atlas and Artemis. When logged into either of these servers from an X terminal, a graphical interface for Mathematica can be run by typing

atlas 7 % mathematica &

Within this graphical interface, you can intermingle text, Mathematica programming commands and their output, graphics and animation in a single document or notebook. This interface also makes it easy to print your notebooks on one of the laser printers.

If you are not at a graphics terminal, you may still run Mathematica (but without the ability to see graphical output) by using the terminal interface, accessed by typing

atlas 8 % math

This terminal interface may also be used from within an X window; any graphical output will be displayed in its own window, created at the time of output.

The Mathematica Programming Language

The best way to become familiar with the Mathematica language is to delve into a few examples. By typing in a few sample commands and modifying them, you will get a feel for the syntax of the programming language, and also learn some of the potential capabilities of Mathematica. Some example commands with a calculus flavor and one from spline theory are listed below with their output to get you started.

Two Things to Note Before Beginning:

Mathematica is case-sensitive; all commands begin with a capital letter, and many have interspersed capitals as well.
"Exit" ends your Mathematica session.

Examples

A Bessel function of the first kind:
Input:
```
Plot[BesselJ[1, x], {x,-20,20}]
```
Output:

A helicoid parametric surface:

Input:

ParametricPlot3D[{t/3, u Cos[t], u Sin[t]}, {t,0,10}, {u,-1,1}]

Output:
[helicoid surface plot]

The 2nd partial derivative of a hyperbolic function with respect to x:

Input:

Simplify[D[2x Sinh[x y]^3, {x,2}]]

Output:

3 y Sinh[x y] (x y + 3 x y Cosh[2 x y] + 2 Sinh[2 x y])

and its graph:

Input:

Plot3D[%, {x,-1,1}, {y,-1,1}]

Output:
[Plot of 2nd partial derivative of a hyperbolic function]

An exponential function definition (definitions have no output):

Input:

g[u_]:=E^(-((x-u)^2)/(4k t))

and its integral, evaluated symbolically from 0 to a:

Input:

Simplify[Integrate[g[u],{u,0,a}]]

Output:

                                    a - x                      x
Sqrt[k] Sqrt[Pi] Sqrt[t] (Erf[-----------------] + Erf[-----------------])
                              2 Sqrt[k] Sqrt[t]        2 Sqrt[k] Sqrt[t]

Now the temperature at time t and point x along an infinite rod with initial hot spot at the origin and heat diffusivity k can be found by the limit:

Input:

Limit[%/(2a Sqrt[Pi k t]),a->0]

Output:

            1
--------------------------
    2
   x /(4 k t)
2 E           Sqrt[k Pi t]

Setting k=1, we can plot this temperature distribution through time as a surface:

Input:

k=1;
Plot3D[%,{t,.01,.5}, {x,-1,1},
         PlotPoints->30,
         PlotRange->All,
         AxesLabel->{"t","x",None}]

Output:
[Heat distribution]

Following are a suite of functions that define and plot a triangular Bernstein basis function defined via barycentric coordinates. The domain triangle's vertex coordinates are stored in the lists xrow and yrow, in counter-clockwise order.

Input:

xrow={2,1,3};
yrow={3,1,1.5};

BaryCoords[x_,y_]:=Chop[LinearSolve[{{1,1,1}, xrow, yrow}, {1,x,y}]];

BernsteinBasis[i_,j_,k_,x_,y_]:=Module[
    {b = BaryCoords[x,y]},
    Which[ b[[1]]<0 || b[[2]]<0 || b[[3]]<0, 0,
           j+k==0, b[[1]]^i,
           i+k==0, b[[2]]^j,
           i+j==0, b[[3]]^k,
           i==0, (j+k)!/(j! k!) b[[2]]^j b[[3]]^k,
           j==0, (i+k)!/(i! k!) b[[1]]^i b[[3]]^k,
           k==0, (i+j)!/(i! j!) b[[1]]^i b[[2]]^j,
           True, (i+j+k)!/(i! j! k!) b[[1]]^i b[[2]]^j b[[3]]^k] ]

PlotBB[i_,j_,k_]:=Plot3D[Evaluate[BernsteinBasis[i,j,k,x,y]],
                         {x,Min[xrow],Max[xrow]},
                         {y,Min[yrow],Max[yrow]},
                         PlotRange->{0,BernsteinBasis[i,j,k,
                                                         ({i,j,k}.xrow)/(i+j+k),
                                                         ({i,j,k}.yrow)/(i+j+k)]},
                         PlotPoints->100, ClipFill->None,
                         Mesh->False]

The functions BernsteinBasis[i,j,k,x,y], for all integers i+j+k=d, form a basis for the space of bivariate polynomials of total degree d defined over the triangle T. Here, we view a quintic basis function:

Input:

PlotBB[1,3,1]

Output:
[Quintic triangular Bernstein basis function]

[More examples under construction]

Input Notes:

Semicolons at the end of an input suppress the display of the output.
"%" denotes the immediately preceding output.
"a b" denotes multiplication of a by b.
"." is the vector/matrix dot product.
"||" is the logical OR operator, "&&" is logical AND.
"=" is used when defining constants, ":=" when defining functions, and "==" within logical constructs (i.e. "a==b" has value "True" if a=b and "False" otherwise.
"Simplify[...]" displays the output of its argument in an often much simpler form.
"Module[{...}, ...]" is a command that allows local variables to be defined (within the initial curly braces) and used within the contents of the module. Mathematica likes modules.
"N[...]" forces a numerical approximation of the argument rather than representing the result exactly.
"Evaluate[...]" is often needed to wrap user-defined functions when they are plotted.

References and Online Help

The thick black hardcover Mathematica manual in the computer room is the definitive guide to the program. For a quick look at more capabilities of Mathematica in algebra, calculus, linear algebra, numerical math and beyond, you might browse the "Tour of Mathematica" section near the beginning. The command index in the back is immensely useful for reviewing what a given command does, and for finding more information and examples elsewhere in the manual.

Within Mathematica, typing ?Foo gives a brief description of command Foo and its syntax. If you are running the notebook interface for Mathematica, the online function browser can also be useful in this regard---just select Help in the top menu.

There are also many extensions to Mathematica which must be loaded into memory in separate packages before gaining access to the additional commands they contain. The Mathematica manual contains examples of several of these useful extensions. You might also browse the thick purple and white softcover Guide to Standard Mathematica Packages for more recent extensions, organized by content.

Including Mathematica Graphics Within Other Documents

See the TeX help page for more information about inserting Mathematica graphics in encapsulated PostScript format into your TeX files.

To insert the (non-animated) mathematica graphics into this webpage, I ran the terminal version of Mathematica from within an X window (on a color graphics workstation) and created GIF files from the resulting Mathematica graphics output windows using the "grab" feature of the nifty picture manipulation program xv. These GIF files can then be called by the corresponding HTML codes to display the pictures within a webpage. To see the xv manual, start up Netscape and enter this URL (which begins with "ftp" rather than the usual "http"):

ftp://username@atlas.math.vanderbilt.edu/usr/local/stow/xv/html/index.html with "username" replaced by your username; you'll be prompted for your password.

The xv manual is also available (and better looking) in postscript; you can see it if you go to an X-Windows terminal and type

gs /usr/local/src/xv/docs/xvdocs.ps

Inserting animated graphics involves another step after the creation of the GIF files (one for each frame of animation). The Animate Page offers a free automated service that collates your GIF files into one animated GIF file which Netscape and other browsers can view (these animated GIF files are called by the corresponding HTML code just like any other picture file).

Version of July 17, 1997 by David Assaf. Modified slightly by webmaster.